da_epsalt_tl.inc
References to this file elsewhere.
1 subroutine da_epsalt_tl(f,t,ssw,epsr,epsi, &
2 TGL_t, TGL_epsr, TGL_epsi )
3
4 !-----------------------------------------------------------------------
5 ! Purpose: returns the complex dielectric constant of sea water, using the
6 ! model of Klein and Swift (1977)
7 !
8 ! Input f = frequency (GHz)
9 ! t = temperature (C)
10 ! ssw = salinity (permil) (if ssw < 0, ssw = 32.54)
11 ! Output epsr,epsi = real and imaginary parts of dielectric constant
12 ! Input : TGL_t (ssw is treated as a constant now)
13 ! Output : TGL_epsr, TGL_epsi, epsr, epsi
14 !-----------------------------------------------------------------------
15
16 implicit none
17
18
19 real, intent(in ) :: f, t, TGL_t
20 real, intent(inout) :: ssw
21 real, intent( out) :: TGL_epsr, TGL_epsi, epsr, epsi
22
23 complex :: cdum1,cdum2,cdum3
24 complex :: TGL_cdum1,TGL_cdum2,TGL_cdum3
25 real :: pi
26 parameter (pi = 3.14159265)
27 real :: ssw2,ssw3,t2,t3,es,a,esnew,tau,b,sig,taunew
28 real :: delt,delt2,beta,signew,om
29 real :: TGL_t2,TGL_t3,TGL_es,TGL_a,TGL_esnew,TGL_tau,TGL_b,TGL_taunew
30 real :: TGL_delt,TGL_delt2,TGL_beta,TGL_signew
31
32 if (ssw .lt. 0.0) ssw = 32.54
33 ssw2 = ssw*ssw
34 ssw3 = ssw2*ssw
35 t2 = t*t
36 TGL_t2 = 2.*t*TGL_t
37 t3 = t2*t
38 TGL_t3 = TGL_t2*t + t2*TGL_t
39 es = 87.134 - 1.949e-1*t - 1.276e-2*t2 + 2.491e-4*t3
40 TGL_es = - 1.949e-1*TGL_t - 1.276e-2*TGL_t2 + 2.491e-4*TGL_t3
41
42 a = 1.0 + 1.613e-5*ssw*t - 3.656e-3*ssw + 3.21e-5*ssw2 - &
43 4.232e-7*ssw3
44 TGL_a = 1.613e-5*ssw*TGL_t
45 esnew = es*a
46 TGL_esnew = TGL_es*a + es*TGL_a
47
48 tau = 1.768e-11 - 6.086e-13*t + 1.104e-14*t2 - 8.111e-17*t3
49 TGL_tau = - 6.086e-13*TGL_t + 1.104e-14*TGL_t2 - 8.111e-17*TGL_t3
50 b = 1.0 + 2.282e-5*ssw*t - 7.638e-4*ssw - 7.760e-6*ssw2 + &
51 1.105e-8*ssw3
52 TGL_b = 2.282e-5*ssw*TGL_t
53 taunew = tau*b
54 TGL_taunew = TGL_tau*b + tau*TGL_b
55
56 sig = ssw*(0.182521 - 1.46192e-3*ssw + 2.09324e-5*ssw2 - &
57 1.28205e-7*ssw3)
58 delt = 25.0 - t
59 TGL_delt = - TGL_t
60 delt2 = delt*delt
61 TGL_delt2 = 2.*delt*TGL_delt
62 beta = 2.033e-2 + 1.266e-4*delt + 2.464e-6*delt2 &
63 - ssw*(1.849e-5 - 2.551e-7*delt + 2.551e-8*delt2)
64 TGL_beta = 1.266e-4*TGL_delt + 2.464e-6*TGL_delt2 &
65 - ssw*(-2.551e-7*TGL_delt + 2.551e-8*TGL_delt2)
66 signew = sig*exp(-beta*delt)
67 TGL_signew = - signew*(TGL_beta*delt+beta*TGL_delt)
68
69 om = 2.0e9*pi*f
70 cdum1 = cmplx(0.0,om*taunew)
71 TGL_cdum1 = cmplx(0.0,om*TGL_taunew)
72 cdum2 = cmplx(0.0,signew/(om*8.854e-12))
73 TGL_cdum2 = cmplx(0.0,TGL_signew/(om*8.854e-12))
74
75 cdum3 = 4.9 + (esnew-4.9)/(1.0 + cdum1) - cdum2
76 TGL_cdum3 = TGL_esnew/(1.0 + cdum1) &
77 - TGL_cdum1*(esnew-4.9)/((1.0 + cdum1)*(1.0 + cdum1)) &
78 - TGL_cdum2
79 epsr = real(cdum3)
80 TGL_epsr = real(TGL_cdum3)
81 epsi = -aimag(cdum3)
82 TGL_epsi = -aimag(TGL_cdum3)
83
84 end subroutine da_epsalt_tl
85
86