da_ao_stats_geoamv.inc

1 subroutine da_ao_stats_geoamv (stats_unit, iv, re)
2 
3    !-------------------------------------------------------------------------
4    ! Purpose: Calculates (Obs - Analysis) statistics for Geo.  AMV's
5    !
6    !-------------------------------------------------------------------------
7 
8    implicit none
9 
10    integer,        intent(in)    :: stats_unit    ! Output unit for stats.
11    type (iv_type), intent(inout) :: iv            ! iv
12    type (y_type),  intent(in)    :: re            ! A - O
13 
14    type (stats_geoamv_type) :: stats
15    integer                  :: nu, nv
16    integer                  :: n, k
17 
18    if (trace_use_dull) call da_trace_entry("da_ao_stats_geoamv")
19 
20    nu = 0
21    nv = 0
22 
23    stats%maximum%u = maxmin_type (missing_r, 0, 0)
24    stats%maximum%v = maxmin_type (missing_r, 0, 0)
25    stats%minimum%u = maxmin_type(-missing_r, 0, 0)
26    stats%minimum%v = maxmin_type(-missing_r, 0, 0)
27 
28    stats%average = residual_geoamv1_type (0.0, 0.0)
29    stats%rms_err = stats%average
30 
31    do n=1, iv%info(geoamv)%nlocal
32       if (iv%info(geoamv)%proc_domain(1,n)) then
33          do k=1, iv%info(geoamv)%levels(n)
34             call da_stats_calculate (n, 0, iv%geoamv(n)%u(k)%qc, & 
35                re%geoamv(n)%u(k), nu, & 
36                stats%minimum%u, stats%maximum%u, &
37                stats%average%u, stats%rms_err%u)
38             call da_stats_calculate (n, 0, iv%geoamv(n)%v(k)%qc, & 
39                re%geoamv(n)%v(k), nv, & 
40                stats%minimum%v, stats%maximum%v, &
41                stats%average%v, stats%rms_err%v)
42          end do
43       end if
44    end do
45 
46    ! Do inter-processor communication to gather statistics.
47    call da_proc_sum_int (nu)
48    call da_proc_sum_int (nv)
49    iv%nstats(geoamv) = nu + nv
50 
51    call da_proc_stats_combine(stats%average%u, stats%rms_err%u, &
52       stats%minimum%u%value, stats%maximum%u%value, &
53       stats%minimum%u%n, stats%maximum%u%n, &
54       stats%minimum%u%l, stats%maximum%u%l)
55    call da_proc_stats_combine(stats%average%v, stats%rms_err%v, &
56       stats%minimum%v%value, stats%maximum%v%value, &
57       stats%minimum%v%n, stats%maximum%v%n, &
58       stats%minimum%v%l, stats%maximum%v%l)
59 
60    if (rootproc) then
61       if (nu /= 0 .or. nv /= 0) then
62          write(unit=stats_unit, fmt='(/a/)') ' Diagnostics of AO for geoamv'
63          call da_print_stats_geoamv (stats_unit, nu, nv, stats)
64       end if
65    end if
66 
67    if (trace_use_dull) call da_trace_exit("da_ao_stats_geoamv")
68 
69 end subroutine da_ao_stats_geoamv  
70 
71