; Example series of plotting meteograms with WRF ARW model data
; First let's just get and plot t2 at a point
; Add some into to the plot


;***********************************************
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"
;***********************************************
begin
;***********************************************

a = addfile("./wrfout_d01_2000-01-24_12:00:00.nc","r")

  t2    = wrf_user_getvar(a,"T2",-1)    ; get t2 for all times
  t2_point  = t2(:,18,20)               ; extract a time series at a point

  taus = (/ 1., 2., 3., 4., 5. /)       ; create a time reference

; get time information and strip out the day and hour
  times_in_file = a->Times
  dims = dimsizes(times_in_file)
  times = new(dims(0),string)
  do i=0,dims(0)-1
    times(i) = chartostring(times_in_file(i,8:12))
  end do

  wks = gsn_open_wks("x11","meteo2")     ; open a workstation

  t2_res = True
  t2_res@tmXBMode       = "Explicit"    ; Define own tick mark labels.
  t2_res@tmXBValues     = taus          ; location of explicit labels
  t2_res@tmXBLabels     = times         ; labels are the locations
  t2_res@tmXTOn         = False         ; turn off the top tick marks
  t2_res@xyLineThicknesses = 2          ; increase line thickness
  t2_res@xyLineColor    =  "blue"       ; set line color

  t2_plot  = gsn_csm_xy(wks,taus,t2_point,t2_res)

end