DOUBLE PRECISION FUNCTION DLANSY( NORM, UPLO, N, A, LDA, WORK ) 1,3
!
! -- LAPACK auxiliary routine (version 3.1) --
! Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
! November 2006
!
! .. Scalar Arguments ..
CHARACTER NORM, UPLO
INTEGER LDA, N
! ..
! .. Array Arguments ..
DOUBLE PRECISION A( LDA, * ), WORK( * )
! ..
!
! Purpose
! =======
!
! DLANSY returns the value of the one norm, or the Frobenius norm, or
! the infinity norm, or the element of largest absolute value of a
! real symmetric matrix A.
!
! Description
! ===========
!
! DLANSY returns the value
!
! DLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'
! (
! ( norm1(A), NORM = '1', 'O' or 'o'
! (
! ( normI(A), NORM = 'I' or 'i'
! (
! ( normF(A), NORM = 'F', 'f', 'E' or 'e'
!
! where norm1 denotes the one norm of a matrix (maximum column sum),
! normI denotes the infinity norm of a matrix (maximum row sum) and
! normF denotes the Frobenius norm of a matrix (square root of sum of
! squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
!
! Arguments
! =========
!
! NORM (input) CHARACTER*1
! Specifies the value to be returned in DLANSY as described
! above.
!
! UPLO (input) CHARACTER*1
! Specifies whether the upper or lower triangular part of the
! symmetric matrix A is to be referenced.
! = 'U': Upper triangular part of A is referenced
! = 'L': Lower triangular part of A is referenced
!
! N (input) INTEGER
! The order of the matrix A. N >= 0. When N = 0, DLANSY is
! set to zero.
!
! A (input) DOUBLE PRECISION array, dimension (LDA,N)
! The symmetric matrix A. If UPLO = 'U', the leading n by n
! upper triangular part of A contains the upper triangular part
! of the matrix A, and the strictly lower triangular part of A
! is not referenced. If UPLO = 'L', the leading n by n lower
! triangular part of A contains the lower triangular part of
! the matrix A, and the strictly upper triangular part of A is
! not referenced.
!
! LDA (input) INTEGER
! The leading dimension of the array A. LDA >= max(N,1).
!
! WORK (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
! where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
! WORK is not referenced.
!
! =====================================================================
!
! .. Parameters ..
DOUBLE PRECISION ONE, ZERO
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
! ..
! .. Local Scalars ..
INTEGER I, J
DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
! ..
! .. External Subroutines ..
! EXTERNAL DLASSQ
! ..
! .. External Functions ..
! LOGICAL LSAME
! EXTERNAL LSAME
! ..
! .. Intrinsic Functions ..
INTRINSIC ABS, MAX, SQRT
! ..
! .. Executable Statements ..
!
IF( N.EQ.0 ) THEN
VALUE = ZERO
ELSE IF( LSAME( NORM, 'M' ) ) THEN
!
! Find max(abs(A(i,j))).
!
VALUE = ZERO
IF( LSAME( UPLO, 'U' ) ) THEN
DO 20 J = 1, N
DO 10 I = 1, J
VALUE = MAX( VALUE, ABS( A( I, J ) ) )
10 CONTINUE
20 CONTINUE
ELSE
DO 40 J = 1, N
DO 30 I = J, N
VALUE = MAX( VALUE, ABS( A( I, J ) ) )
30 CONTINUE
40 CONTINUE
END IF
ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR. &
( NORM.EQ.'1' ) ) THEN
!
! Find normI(A) ( = norm1(A), since A is symmetric).
!
VALUE = ZERO
IF( LSAME( UPLO, 'U' ) ) THEN
DO 60 J = 1, N
SUM = ZERO
DO 50 I = 1, J - 1
ABSA = ABS( A( I, J ) )
SUM = SUM + ABSA
WORK( I ) = WORK( I ) + ABSA
50 CONTINUE
WORK( J ) = SUM + ABS( A( J, J ) )
60 CONTINUE
DO 70 I = 1, N
VALUE = MAX( VALUE, WORK( I ) )
70 CONTINUE
ELSE
DO 80 I = 1, N
WORK( I ) = ZERO
80 CONTINUE
DO 100 J = 1, N
SUM = WORK( J ) + ABS( A( J, J ) )
DO 90 I = J + 1, N
ABSA = ABS( A( I, J ) )
SUM = SUM + ABSA
WORK( I ) = WORK( I ) + ABSA
90 CONTINUE
VALUE = MAX( VALUE, SUM )
100 CONTINUE
END IF
ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
!
! Find normF(A).
!
SCALE = ZERO
SUM = ONE
IF( LSAME( UPLO, 'U' ) ) THEN
DO 110 J = 2, N
CALL DLASSQ
( J-1, A( 1, J ), 1, SCALE, SUM )
110 CONTINUE
ELSE
DO 120 J = 1, N - 1
CALL DLASSQ( N-J, A( J+1, J ), 1, SCALE, SUM )
120 CONTINUE
END IF
SUM = 2*SUM
CALL DLASSQ( N, A, LDA+1, SCALE, SUM )
VALUE = SCALE*SQRT( SUM )
END IF
!
DLANSY = VALUE
RETURN
!
! End of DLANSY
!
END FUNCTION DLANSY